use warnings;
use strict;
use Getopt::Long;
use File::Basename;
use Time::Local;

our $VERSION = '1.01';
my $debug = 1;


main();

sub main {
    
    my %opt;
    
    GetOptions('help'          => \$opt{help},
               'nano2human=s'  => \$opt{nano2human},
               'human2nano=s'  => \$opt{human2nano},
               ) or die "Errors encountered while parsing command line options: $! -- $^E\n";
    
    parse_args(\%opt);
    
    if ($opt{nano2human}) {
        
        print_help("Malformed nano time (non-digits found): $opt{nano2human}\n") if $opt{nano2human} =~ /\D/;
        
        nano2human($opt{nano2human});
        
    }
    
    if ($opt{human2nano}) {
        
        human2nano($opt{human2nano});
        
    }
    
}


sub print_help {
    
    my @message = @_;
    
    my $script_name = basename $0;
    
    print <<EOF;
$script_name v$VERSION

Usage: $script_name [--help] [--nano2human "100th nanoseconds"] 
                    [--human2nano "year-month-day hour:minute:second"]

--help       : Print this help text.
--nano2human : Enter 100th nanoseconds as used by for instance the
               lastLogon LDAP/AD attribute on Windows, and get a human-
               readable date back.
--human2nano : Enter a human-readable date in the format:
               "year-month-day hour:minute:second", and get the 100th
               nanosecond timestamp back.

Author: Joakim Svendsen, Svendsen Tech, svendsentech@gmail.com

MIT License.

EOF
    
    print @message, "\n" if @message;
    exit;
    
}


sub nano2human {
    
    my $wintime = shift;
    
    my $unix_epoch = win_to_unix_epoch($wintime);
    
    my ($year, $month, $day, $hour, $minute, $second) = (localtime $unix_epoch)[5,4,3,2,1,0];
    
    $year  += 1900;
    $month += 1;
    
    ($month, $day, $hour, $minute, $second) = map { sprintf '%02d', $_ } $month, $day, $hour, $minute, $second;
    
    print "100th ns (Wintime): $wintime | Date: " . join('-', $year, $month, $day) . ' ' . join(':', $hour, $minute, $second);
    print "\n";
    
}


sub human2nano {
    
    my $date = shift;
    
    if ($date =~ /^(\d{4})-(\d\d)-(\d\d)\s+(\d\d):(\d\d):(\d\d)$/) {
        
        my ($year, $month, $day, $hour, $minute, $second) = ($1, $2, $3, $4, $5, $6);
        
        # Conform to localtime() standards as used by Time::Local
        $year   -= 1900;
        $month  -= 1;
        
        my $unix_epoch = timelocal($second, $minute, $hour, $day, $month, $year);
                
        my $win_epoch = unix_to_win_epoch($unix_epoch);
        
        print "Date: $date | 100th ns (Wintime): $win_epoch\n";
        
    }
    
    else {
        
        print_help(qq{ERROR: Malformed date specified: $date\nValid example: '2000-12-24 20:00:00'.\nRemember double quotes ("") around the --human2nano argument});
        
    }
    
}


sub parse_args {
    
    my $opt = shift;
    
    print_help('') if $opt->{help};
    
    unless ($opt->{nano2human} or $opt->{human2nano}) {
        
        print_help("Warning: Please specify either --nano2human, --human2nano or both\n");
        
    }
    
}


sub win_to_unix_epoch {
    
    # Actually hundreds of nanoseconds at this point...
    my $nanoseconds = shift;
    
    # Get seconds
    my $seconds = $nanoseconds / 10_000_000;
    
    # This magic number is the difference between Unix and Windows epoch.
    my $unix_epoch = $seconds - 11644473600;
    
    # Return the Unix epoch for use with localtime().
    return $unix_epoch;
    
}


sub unix_to_win_epoch {
    
    my $unix_epoch = shift;
    
    my $winseconds = $unix_epoch + 11644473600;
    
    my $win_epoch = sprintf '%.0f', ($winseconds * 10_000_000);
    
    return $win_epoch;
    
}