use warnings;
use strict;
use Getopt::Long;
use File::Basename;


## Author: Svendsen Tech, Joakim Svendsen
## Mail: joakimbs using Google's mail service
## Created: 2008-07-25
## Rewritten: 2011-12-27

# Declare options hash and parse command line parameters
my %options;
GetOptions(
           'dryrun'     => \$options{dryrun},
           'help'       => \$options{help},
           'nonverbose' => \$options{nonverbose},
           'subst=s'    => \$options{subst},
           'glob=s'     => \$options{glob}
           )
    or die "Unable to parse arguments: $!\n$^E";

# Print help if -h was supplied or the required arguments are missing
if ($options{help} or !$options{subst} or !$options{glob}) {
    
    my $script_name = basename $0;
    
    print <<EOF;

$script_name : Rename a set of files according to a Perl substitution
             or transliteration expression. Created by Svendsen Tech.
             Author: Joakim Svendsen

Usage: $script_name --subst "perl subst/tr expression" -glob "glob"
[--help] [--dryrun] [--nonverbose]

--help:  Print this help text.
--subst: Perl substitution expression or transliteration, as seen on the right
         hand side of the binding operator "=~" - usually s///. Each filename
         in "glob" will be renamed according to this.
--glob:  File glob as expanded by perl's glob() function. perldoc -f glob.
         For instance "*.mp3" to target all mp3 files.
--dryrun: Do a "dry run", meaning files won't be renamed, but you will see
          exactly what the script would do as output to the console. You
          will get output even if you specify --nonverbose.
--nonverbose: Non-verbose (no output). Not in effect on dry runs.


See perldoc perlre for a list of available flags and more information about
Perl regular expressions. See perldoc perlop for a description of s/// and
tr///. perldoc perlretut may also be of interest.

If an argument contains no spaces or shell meta characters, the quotes can
be omitted. If you are calling this from PowerShell, use a single-quoted
string and q() and qq() for strings inside the single-quoted string.

See http://www.powershelladmin.com/wiki/Rename_unix_utility_-_windows_port
for more information.

Examples:
$script_name -s s/\.txt\$/.log/ -g *.txt   - renames txt files to log files.
$script_name -s tr/A-Z/a-z/ -g *.mp3  - makes "A-Z" in mp3 files all lowercase.
EOF
    
    exit;
    
}

# Place arguments in more suitably named variables.
my $subst = $options{subst};
my $glob  = $options{glob};

# Just exit if there aren't any files matching the glob pattern.
die "No files matched by glob\n" unless my @files = glob($glob);

# Set verbosity flag according to whether or not -nonverbose was supplied.
# $verbose being set to a true value means output will be printed. The
# default is to print output to STDOUT.
my $verbose = $options{nonverbose} ? 0 : 1;

# Dry run flag. The default is renaming for real.
my $dry_run = $options{dryrun} ? 1 : 0;

for my $file (@files) {
    
    my $new_filename = $file;
    
    # Yeah, eval.
    eval "\$new_filename =~ $subst";
    
    if ($@) {
        
        # Oh no!
        die "Error in eval: $!\n$^E"
        
    }
    
    # If a change has been made to the string:
    if ($file ne $new_filename) {
        
        if ($dry_run) {
            
            printf '%-40s - %s', "Would rename '$file'", "to '$new_filename'\n";
            
        }
        
        else {
            
            # If the file is successfully renamed, print this:
            if (rename $file, $new_filename) {
                
                printf '%-40s - %s', "Renamed '$file'", "to '$new_filename'\n" if $verbose;
                
            }
            
            # If the file was NOT successfully renamed, print this:
            else {
            
                print '%-40s - %s', "FAILED to rename '$file'", "to '$new_filename':\n$!\n$^E" if $verbose;
            
            }
            
        }
        
    }
    
    # No substitution was made. No match?
    else {
        
        print "'$file' ", $dry_run ? "wouldn't" : "didn't", " change its name\n" if ($verbose or $dry_run);
        
    }
    
}